<MvFOREACH>

When combined with the -C (compatibility) compiler flag, MvFOREACH generates code that will run on any engine version 5.00 or newer, using runtime engine version checks to either call these functions or emulate their behavior.

Attributes

• ITERATOR: Required, the name of a variable which will contain a specific element in the array. The mechanism used is the same as <MvREFERENCE> and <MvREFERENCEARRAY>.
• ARRAY: Required, the array over which to iterate.
• INDEX: Optional, the name of the variable that is used to track the iterations through the loop. When specified, the variable can be used inside the expressions for the NEXT and LAST attributes, and is present within the MvFOREACH loop. If omitted an internal variable is used.
• FIRST: Optional expression defines the index of the first element to iterate. If omitted, the loop starts at the first element present in the array (* see below).
• NEXT: Optional expression is called at the end of the loop to increment the INDEX variable. If omitted, the loop transitions to the next element present in the array (* see below).
• LAST: Optional expression, defines the upper bound of the loop, that is last element to iterate. If omitted, the loop terminates after the last element in the array. (* see below).
• COUNT: Optional: is shorthand for dealing with known-dense arrays. It sets the loop up to iterate from 1 to COUNT, incrementing by1 each time. It has some performance advantages when proper handling of sparse arrays is not a concern. (* see below).

* Only the ITERATOR and ARRAY elements are required. When COUNT is specified, FIRST, NEXT, and LAST must be omitted. When COUNT is omitted, FIRST, NEXT, and LAST may be used together in any combination. When NEXT is used the expression must increment the INDEX.

Examples:

This example use <MvFOREACH> in it simplest form to output a number list of orders. The functions miva_array_min() and miva_array_max() are called internally to determine the first and last elements to efficiently traverse sparse arrays.

<MvFOREACH ITERATOR = "l.item" ARRAY = "l.orders" INDEX = "l.pos">
    <MvEVAL EXPR = "{ l.pos }">. <MvEVAL EXPR = "{ l.item:Fname }"> <MvEVAL EXPR = "{ l.item:Lname }"><br>
</MvFOREACH>

This variation limits output to 25 items by using the COUNT attribute. It assumes no array elements are empty and the number of items is known. Remember you can not use COUNT with FIRST, NEXT and LAST.

<MvASSIGN NAME = "l.items_per_page" VALUE = "{ 25 }">

<MvFOREACH ITERATOR = "l.item" ARRAY = "l.orders" INDEX = "l.pos" COUNT = "{ l.items_per_page }">
    <MvEVAL EXPR = "{ l.pos }">. <MvEVAL EXPR = "{ l.item:Fname }"> <MvEVAL EXPR = "{ l.item:Lname }"><br>


</MvFOREACH>

This example works exactly the same but allows you to control the loop more precisely by specifying parameters.

<MvASSIGN NAME="l.items_per_page" VALUE="{ 25 }">

<MvFOREACH ITERATOR = "l.item"
           ARRAY = "l.orders"
           INDEX = "l.pos"
           FIRST = "{ 1 }"
           NEXT = "{ l.pos + 1 }"
           LAST = "{ l.items_per_page }">

    <MvEVAL EXPR = "{ l.pos }">. <MvEVAL EXPR = "{ l.item:Fname }"> <MvEVAL EXPR = "{ l.item:Lname }"><br>
</MvFOREACH>

By incrementing the variable g.page_num the next page of 25 items in the array can be output.

<MvASSIGN NAME="g.page_num" VALUE="{ g.page_num  + 1 }">

<MvASSIGN NAME="l.items_per_page" VALUE="{ 25 }">
<MvASSIGN NAME="l.first" VALUE="{ ((g.page_num  - 1) * l.items_per_page) + 1 }">
<MvASSIGN NAME="l.last" VALUE="{ l.first + l.items_per_page - 1 }">

<MvFOREACH ITERATOR = "l.item"
           ARRAY = "l.orders"
           INDEX = "l.pos"
           FIRST = "{ l.first }"
           NEXT = "{ l.pos + 1 }"
           LAST = "{ l.last }">

    <MvEVAL EXPR = "{ l.pos }">. <MvEVAL EXPR = "{ l.item:Fname }"> <MvEVAL EXPR = "{ l.item:Lname }"><br>
</MvFOREACH>

This example loops through the orders array skipping any "test orders" by using <MvFOREACHCONTINUE> or exiting the loop if an error occurs by using  <MvFOREACHSTOP>.

<MvFOREACH ITERATOR = "l.item" ARRAY = "l.orders" INDEX = "l.pos" COUNT = "{ 100 }">

    <MvCOMMENT> filter out any test orders </MvCOMMENT>
    <MvIF EXPR="{ 'test order' IN l.item:fname }">
        <MvFOREACHCONTINUE>
    </MvIF>

    <MvCOMMENT> If this field is empty display an error and exit the loop. </MvCOMMENT>
    <MvIF EXPR="{ ISNULL l.item:code }">
        <MvEVAL EXPR="{ 'Error in order number ' $ l.item:id $ '. code not found.' }">
    <MvFOREACHSTOP>
</MvIF>

</MvFOREACH>