<MvFOR>

Loops through the code between <MvFOR> and </MvFOR> the number of time specified between first and last, incrementing the index. Optionally you can exit the loop using <MvFORSTOP>.

Loops execute a block of code a specified number of times, or while a specified condition is true. <MvFOR> can create the simplest of loops or execute more complex loop.

Attributes

• INDEX: Optional, the name of the variable that is used to track the iterations through the loop. When specified, the variable can be used inside the expressions for the EXPR, NEXT and LAST attributes, and is present inside the MvFOR loop. If omitted an internal variable is used.
• FIRST: Optional numeric expression defines the low-end range of the loop. This expression is executed only once, at the beginning of the <MvFOR> block.
• NEXT: Optional expression. If specified the is expression called at the end of each iteration to increment the INDEX variable. If omitted, the index variable is incremented by one for each pass through the loop.
• LAST: Expression defines the high-end of the loop (inclusive). This expression is executed at the beginning of the loop and also at every iteration through the loop, allowing you to perform interesting operations, such as calling a function. If you use a simple expression here with a static value or simple variable, there is no performance overhead by evaluating the expression after every iteration  (* see below).
• COUNT: is a shorthand for an extremely simple loop which iterates from 1 to the value of the COUNT expression, incrementing by 1 after each iteration. Unlike LAST, the expression in COUNT is executed only once, at the beginning of the loop (* see below).
• EXPR is a boolean expression that is evaluated at the beginning of each iteration through the loop. If it resolves to a true value, the loop continues. Otherwise, the loop terminates (* see below).

* Exactly one of COUNT, LAST, or EXPR must be specified. All other attributes are optional. When NEXT is used the expression must increment the INDEX

Examples

In it simplest form only the COUNT is specified. If the INDEX is specified the variable becomes available within the loop.

<MvFOR COUNT = "{ 100 }">

</MvFOR>

<MvFOR INDEX = "l.pos" COUNT = "{ 100 }">
   <MvEVAL EXPR = "{ l.pos }"><br>
</MvFOR>

This number of iterations this loop performs is based on a variable in the LAST attribute. It loops from 1 to the l.high value incrementing the variable l.pos by 1 on each pass. In addition it illustrated the <MvFORCONTINUE> and <MvFORSTOP> tags.

<MvASSIGN NAME="l.high" VALUE="{ miva_array_max(l.orders) }">

<MvFOR INDEX = "l.pos" FIRST = "{ 1 }" NEXT = "{ l.pos + 1 }" LAST = "{ l.high }">

    <MvCOMMENT> Skip the code every third loop </MvCOMMENT>
    <MvIF EXPR="{ l.pos MOD 3 }">
        <MvFORCONTINUE>
    </MvIF>

    <MvCOMMENT> If this field is empty display an error and exit the loop. </MvCOMMENT>
    <MvIF EXPR="{ ISNULL l.orders[l.pos]:fname }">
        <MvEVAL EXPR="{ 'Error in order number ' $ l.orders[l.pos]:id $ '. first name not found.' }">
    <MvFORSTOP>
</MvFOR>

This example steps through the loop backwards, numbered 100 to 0, by a value of 10. Since the NEXT parameter must increment, a math calculation is used to count backwards. This could be used as a pointer to an array allowing you to iterate in reverse order.

<MvASSIGN NAME="l.max" VALUE="{ 100 }">
<MvFOR INDEX = "l.pos" FIRST = "{ 1 }" NEXT = "{ l.pos + 10 }" LAST = "{ l.max }">
    <MvASSIGN NAME="l.ndx" VALUE="{ l.max + 1 - l.pos }">
    <MvEVAL EXPR = "{ l.ndx }">,
</MvFOR>

Output: 100,90,80,70,60,50,40,30,20,10,

The EXPR attribute is similar that found in the <MvWHILE> tag. The expression is evaluated at the beginning of each loop and while the expression evaluates as true (not zero), the loop continues.

This examples processes 100 records, or as many as it finds. This could be used as an alternative to using <MvFORSTOP> to exit a loop.

<MvASSIGN NAME="l.found" VALUE="{ Get_First_Record(l.data) }">
<MvFOR INDEX = "l.pos" COUNT = "{ 100 }" EXPR = "{ l.found }">

    ...process the record then get the next one...

   <MvASSIGN NAME="l.found" VALUE="{ Get_Record(l.pos, l.data) }">
</MvFOR>

OR alternatively...

<MvFOR INDEX = "l.pos" COUNT = "{ 100 }" EXPR = "{ Get_Record(l.pos, l.data) }">

    ...process 100 records if found...

</MvFOR>